# 請先確認你身上有藍魔礦、你有傳送的技能、你有 yuno_fild11 的傳送記憶點、重生點設在朱諾,鎖定地圖為 yuno_fild11
automacro autoWarp {
run-once 1
# 剛從朱諾南邊出來的地圖座標
location yuno_fild04 231 284
# 檢查身上有無藍色魔力礦石
inventory "藍色魔力礦石" > 0
# 以上兩個條件都符合的話,才觸發以下的巨集
call {
# 施展傳送之陣於座標 226 282
do sl 27 226 282
pause 2
# 選擇傳送地圖為 yuno_fild11
do warp yuno_fild11
pause 3
# 移動至新開的傳陣
do move 226 282
pause 2
release autoWarp
}
}


 


 


施放傳陣前往鎖定地圖-改良版(回城時也自動施放傳陣回城



automacro warpTrigger {
        #當地圖是pay_fild03 388 63或pay_fild03 313 19觸發
        location pay_fild03 388 63,pay_fild03 313 19
        #身上藍石要大於0
        inventory "藍色魔力礦石" > 0
        run-once 1
        call autowarp
}
macro autowarp {
        #當座標是388 63時,執行one
        if ($.pos == 388 63) goto one
        #當座標是313 19時,執行two
        if ($.pos == 313 19) goto two
        release warpTrigger
        stop
        :one
                #使用傳陣在座標386 65
                do sl 27 386 65
                pause 2
                #施放通往pay_fild06的傳陣
                do warp pay_fild06
                pause 3
                #移動到座標386 65
                do move 386 65
                pause 2
                release warpTrigger
                stop
        :two
                #使用傳陣在座標311 20
                do sl 27 311 20
                pause 2
                #施放通往alberta的傳陣
                do warp alberta
                pause 3
                #移動到座標311 20
                do move 311 20
                pause 2
                release warpTrigger
                stop
}

創作者介紹
創作者 aaa1314 的頭像
aaa1314

RO相關資料資訊♂外掛腳本討論&請勿發表其他廣告(請保持畫面清爽)感謝

aaa1314 發表在 痞客邦 留言(0) 人氣()